Voodoo Programming » Applescript

Simulating encrypted physical disk in OS X

Constantinos — Wed, 30 Jan 2008 22:01:55 +0000

I’ve always wanted to do this: have my personal files on a memory stick, encrypted, and when I insert the memory stick in a USB port then OS X asks me for a password to decrypt the files. Unfortunately, this functionality isn’t offered directly as you can’t (at least from what I’ve tried and read) encrypt a device directly. What you can do however is create encrypted disk images, and place them in your thumb drive. There are two disadvantages with this method: First the process isn’t automatic, first the drive mounts, then you have to double-click on the encrypted disk image to mount it, and second after you do that you have two volumes on your Desktop. One for the thumb drive, and one for the encrypted image.

Obviously, in my obsessive compulsive need to have everything work as I want them, I didn’t like this. As a result, I created the following scripts (including a folder action) which pretty much simulate the whole experience. These scripts were only tested on 10.5.1, but they should work on at least Tiger.

Update 2008-02-01: Download all the scripts featured on this page in a single archive file.

Update 2008-02-08: The automount and prepare scripts in the download archive were reversed (my mistake) which is now fixed. I also added compatibility for sparsebundle types, and the password entry when preparing a drive is now hidden (thanks John!)

There are two steps to the process. The first step is to prepare the memory stick, and the second is to configure the folder action. The first step only has to be applied once, and works best on a freshly formatted memory stick, however it doesn’t have to be formatted; it will use all the available space to create the encrypted image. Save the following script as an application bundle somewhere, plug in the memory stick you wish to use as your ‘encrypted storage’, and drag-drop the mounted volume on the bundle. It will ask you for a password (which is typed in the clear – fair warning), then after a few minutes (with the default settings) it will finish creating the encrypted image, mark the entire volume as hidden, and eject the drive.

(*
    Prepare secure drive droplet
    Part of 'Simulating encrypted physical disk in OS X' by Constantinos Neophytou
    http://www.cneophytou.com/2008/01/30/simulating-encrypted-physical-disk-in-os-x/
 
    Version 0.1.1
*)
 
property imageType : "UDIF" (* one of "UDIF", "SPARSE" or "SPARSEBUNDLE" - the latter two have faster creation times, but leave empty space on the device *)
property thePass : ""
 
on open dropped_item
    set this_vol_alias to (dropped_item as alias)
    try
        tell application "Finder"
            if the kind of this_vol_alias is "Volume" then
                set freeSpace to free space of this_vol_alias
                set volumeName to quoted form of POSIX path of this_vol_alias
                set imgSize to (round (freeSpace - (1024 * 1024 * 1)) / (1024 * 1024)) (* leave 1mb of free space, just in case *)
 
                display dialog "Enter password for encrypted image:" default answer thePass with hidden answer
                set thePass to text returned of result as string
 
                set createImg to "hdiutil create " & volumeName & ".secure -size " & imgSize & "m -fs HFS+ -type " & imageType & " -encryption -volName Secure -passphrase " & thePass
                set thePass to "" (* clear the password from memory *)
                set hideVol to "chflags hidden " & volumeName
                with timeout of 600 seconds
                    do shell script createImg
                    do shell script hideVol
                    do shell script "hdiutil detach " & quoted form of POSIX path of this_vol_alias
                end timeout
            else
                display alert "This script can only be executed on volumes"
                return
            end if
        end tell
 
    on error error_message number error_number
        display dialog error_message buttons {"OK"} default button 1
    end try
end open

Download all scripts

At this point, the memory stick is configured for use with the folder action. Warning: If you remove the drive and plug it back in without the folder action being in place, the disk will mount but it won’t show up in the Finder. You will have to use Disk Utility or the Terminal to un-mount it. Go ahead and copy the following code, save it as a script under /Library/Scripts/Folder Action Scripts/, and attach it as a folder action to /Volumes.

(*
    Automount secure drive folder action
    Part of 'Simulating encrypted physical disk in OS X' by Constantinos Neophytou
    http://www.cneophytou.com/2008/01/30/simulating-encrypted-physical-disk-in-os-x/
 
    Version 0.1.1
*)
 
property secureName : ".secure"
 
on adding folder items to this_folder after receiving these_volumes
    try
        tell application "Finder"
            set the volume_list to every file of this_folder
            (* go through all entries in /Volumes/ *)
            repeat with i from 1 to number of items in volume_list
                set this_item to the original item of item i of volume_list
                if the kind of this_item is "Volume" then
                    set this_disk to (this_item as alias)
 
                    (* is this item the newly mounted disk? *)
                    if this_disk is in these_volumes then
                        (* iterate through all files in the root of disk *)
                        set searchCmd to "ls -d " & quoted form of POSIX path of this_disk & secureName & "*"
                        (* check to see if a hidden secure image  is available *)
                        set searchResult to ""
                        try
                            set searchResult to do shell script searchCmd
                        end try
                        (* mount the secure image *)
                        if (searchResult starts with "/Volumes") then
                            set hiddenFile to POSIX file searchResult as alias
                            open hiddenFile
                        end if
                    end if
                end if
            end repeat
        end tell
    end try
end adding folder items to
 
on removing folder items from this_folder after losing these_items
    tell application "Finder"
        try
            set the volume_list to every file of this_folder
            (* go through all entries in /Volumes/ *)
            repeat with i from 1 to number of items in volume_list
                set this_item to the original item of item i of volume_list
                if the kind of this_item is "Volume" then
                    set this_disk to (this_item as alias)
 
                    set searchCmd to "ls -d " & quoted form of POSIX path of this_disk & secureName & "*"
                    (* check to see if a hidden secure image  is available *)
                    set searchResult to ""
                    try
                        set searchResult to do shell script searchCmd
                    end try
                    if (searchResult starts with "/Volumes") then
                        (* eject the volume *)
                        do shell script "hdiutil detach " & quoted form of POSIX path of this_disk
                        (* eject this_disk *)
                        delay 1
                        display alert "It is now safe to remove the encrypted disk"
                        return
                    end if
                end if
            end repeat
        end try
    end tell
end removing folder items from

Download all scripts

Now whenever you plug in the thumb drive, this script will kick in and try to open the encrypted image which will in turn make the Finder ask you for a password. Additionally, when you un-mount the encrypted image, it will find the thumb drive and un-mount it as well. You should wait for the confirmation dialog saying it’s safe to remove the device before doing so, as ejecting the encrypted image is not the same as ejecting the drive, the folder action has to kick in and do that for you.

There are a couple of issues with this. The first one, I haven’t been able to find a decent solution for. If after you plug in the memory stick and you’re asked for a password for the encrypted device, you either enter the wrong password three times or press ‘Cancel’, then the encrypted image will not mount, but the memory stick will remain mounted. To eject it, you will have to use Disk Utility or the Terminal. The second one, is reverting the memory stick to its proper state. To do that, I created another script which you can just run by itself, after plugging in the memory stick and pressing ‘Cancel’ when asked for the encrypted image password (i.e. it uses the ‘bad’ state described in the previous problem). When run, the script will find the memory stick that contains the encrypted image and ask if you wish to revert it. If you press ‘Yes’, it will then ask if you wish to preserve the secure image. Pressing ‘Yes’ will move the secure image on your Desktop (under the name secure.dmg), otherwise it will just delete it from the drive. It will also restore the hidden status of the thumb drive and eject it, so the next time you plug it in it will behave normally:

(*
    Restore secure drive
    Part of 'Simulating encrypted physical disk in OS X' by Constantinos Neophytou
    http://www.cneophytou.com/2008/01/30/simulating-encrypted-physical-disk-in-os-x/
 
    Version 0.1.1
*)
 
property secureName : ".secure"
tell application "Finder"
    try
        set the volume_list to every file of (POSIX file "/Volumes/" as alias)
        repeat with i from 1 to number of items in volume_list
            set this_item to the original item of item i of volume_list
            if the kind of this_item is "Volume" then
                set this_disk to (this_item as alias)
 
                set searchCmd to "ls -d " & quoted form of POSIX path of this_disk & secureName & "*"
                (* check to see if a hidden secure image  is available *)
                set searchResult to ""
                try
                    set searchResult to do shell script searchCmd
                end try
                if (searchResult starts with "/Volumes") then
                    display dialog "Restore secure disk " & (name of this_disk) & "?" buttons ["No", "Yes"] default button 2
                    set the_button to button returned of result
                    if (the_button is "Yes") then
                        display dialog "Preserve copy of secure data on Desktop?" buttons ["No", "Yes"] default button 2
                        set the_button to button returned of result
                        if (the_button is "Yes") then
                            with timeout of 600 seconds
                                do shell script "mv " & quoted form of searchResult & " ~/Desktop/secure.dmg"
                            end timeout
                        else
                            do shell script "rm -f " & quoted form of searchResult
                        end if
                        set volumeName to quoted form of POSIX path of this_disk
                        do shell script "chflags nohidden " & volumeName
                        do shell script "hdiutil detach " & volumeName
                        delay 1
                        display alert "Device restored. It is now safe to unplug the device."
                        return
                    end if
                end if
            end if
        end repeat
 
    on error error_message number error_number
        display dialog error_message buttons {"OK"} default button 1
    end try
end tell

Download all scripts

As always, these scripts are provided without any warranty, and any suggested improvements are more than welcome!

Automatically restart crashed applications

Constantinos — Sun, 14 Oct 2007 21:31:07 +0000

I love Quicksilver. If I ever sit on a machine without it, I feel handicapped, like something extremely important is missing. My major gripe with Quicksilver (and, this might just be my setup, I’m not sure), is that it likes to crash a lot. At least 2-3 times a week. And when it crashes, it’s extremely annoying because when I need to start a program up I use, well, Quicksilver!

Updated 2008-01-11: Modified script for Leopard. New script at end of post.

I’ve found a couple of different methods for relaunching Quicksilver easily or automatically. One was to keep an alias to Quicksilver on the bottom-left part of your desktop with no icon, and named as ” ” (i.e. a space). So when Quicksilver is off and you want to start it, you cmd-tab to the Finder, hit space, and cmd-o. Quick, easy, does the job, but hardly clean (or nerdy!).

The other approach which I loved was playing around with launchd (found on MacWorld and macosxhints.com). With this service we can monitor a file for modifications, and when the file is modified we can perform an action. In this case, we would monitor the file /Users/username/Library/Logs/CrashReporter/Quicksilver.crash.log, and once its modified, launch Quicksilver. Clean, fully automated, but hardly simple. To make the task easier, Lingon can be used to deal with launchd. However, I was never able to make this to work, and I don’t have the patience to sit down and figure out what the problem is.

I did like the idea of monitoring Quicksilver.crash.log since that’s a direct indication that the application has crashed, but other than launchd I’m not familiar with any other automated service that can monitor for modifications in a file. I am however familiar with an automated service that monitors for modifications in a folder, courtesy of OS X, and that’s folder actions.

I can therefore build a folder action which will monitor /Users/username/Library/Logs/CrashReporter/ for changes, see what files were added, and if a ‘marked’ file was added then relaunch the relevant application and (this part is critical) delete the crash log so the script can work again. It took a couple of tries, but I think I found the most robust solution for this approach.

property restartLog : {"Quicksilver.crash.log"}
property restartID : {"daed"}
 
on adding folder items to this_folder after receiving these_items
    repeat with i from 1 to number of items in these_items
        set fileAlias to item i of these_items as alias
        set fileInfo to info for fileAlias
        set fileName to name of fileInfo as text
        if fileName is in restartLog then
            beep
            set itm to my list_position(fileName, restartLog)
            tell application "Finder"
                open application file id (item itm of restartID)
                delete item fileAlias
            end tell
        end if
    end repeat
end adding folder items to
 
on list_position(this_item, this_list)
    repeat with i from 1 to the count of this_list
        if item i of this_list is this_item then return i
    end repeat
    return 0
end list_position

Download this script

Note that to get this to work initially, you’ll have to open that folder and delete the existing Quicksilver.crash.log, otherwise this folder action will never kick in for Quicksilver!

The critical part are the two properties at the top. The first property contains the name of the file to watch for, and the second property contains (in the same order as in the first property) the application file id for the related application. The reason for using the application file id is that this will remain constant on every system even if the application is renamed by the user.

This script can be expanded to listen for any number of applications simply by adding the two parameters for each application to these properties. To get the application file id of the application you wish to monitor, simply run this code once in Script Editor while the target application is running:

tell application "Finder" to return creator type of process "Process Name"

and watch the output.

As a side note, with this method you can chose to do any number of things instead of just relaunching the crashed application since it’s straight forward applescript. In my version I chose to ‘beep’ as well, to let me know something went wrong (and the file trash sound is also a giveaway), but you really could do anything you want here.

Leopard Update:

There have been a few changes in the way Leopard handles the crash log files, which simplifies the use of this script. Instead of using a single crash log file for each application and appending to it, Leopard simply creates a new timestamped crash log in the form Name_YYYY-MM-DD-TIME_Hostname.crash. This is easier, because we no longer have to worry about deleting the crash log, we can simply check if the newly added log starts with *Name*. Therefore, a simpler version of the above applescript (that can only work with a single app, but switching to lists shouldn’t be too hard), follows:

property restartName : "Quicksilver"
property restartID : "daed"
 
on adding folder items to this_folder after receiving these_items
    repeat with i from 1 to number of items in these_items
        set fileAlias to item i of these_items as alias
        set fileInfo to info for fileAlias
        set fileName to name of fileInfo as text
        if fileName starts with restartName then
            beep
            tell application "Finder"
                open application file id restartID
            end tell
        end if
    end repeat
end adding folder items to

Download this script

If anyone can figure out how to use applescript instead of the shell commands and still have it work, please let me know.

iTunes scripts I can’t live without

Constantinos — Tue, 24 Jul 2007 18:04:22 +0000

I have few obsessions in my life, and one of those happens to be keeping my iTunes library in some form (and definition) of ‘order’, without having me go completely insane. This involves keeping the ID3 data as accurate as I can make it (very tedious process as I had about 100 songs named Track 3 – Unknown Artist), but that is more or less under control. What I’m working on now is rating all of my music (I’m sure every one has their own rating scheme, and there’s no need to share mine here… Just suffice to say that a 0-star rating means the song hasn’t been reviewed), and also getting as much album artwork to go with iTune’s cover flow so I can use it without looking at the same default image every time…

Doing all this manually would pretty much take up all my time, so over a period of few months (back when I first started dealing with my iTunes library), I built a few applescripts which help me manage all these tasks, and which are bound to keyboard shortcuts in Quicksilver.

Rating

I have all the standard 0-5 star rating scripts, which are bound to cmd-opt-0 through cmd-opt-5 respectively. Since I use Growl, I wanted a notification to come up for this fact, and use the album artwork (if any) as the notification icon. This is the script for the 5 star rating, where for every other (0-4 stars) script the only modification is the actual rating (commented in the script)

property emdash : «data utxt2014» as Unicode text
property black_star : «data utxt272F» as Unicode text
property white_star : «data utxt2606» as Unicode text
property dot : «data utxt00B7» as Unicode text
 
set appName to "GrowlHelperApp"
set app2Name to "iTunes"
 
tell application "System Events"
    set appIsRunning to (name of processes contains appName) and (name of processes contains app2Name)
end tell
 
if appIsRunning then
    tell application "iTunes"
        if class of current track is in {track, file track, URL track, device track, shared track, audio CD} then
            (* Increments of 20, from 0 to 100 for 0 - 5 stars *)
            set rating of current track to 100
        end if
        my notifyTrack(current track, player position, "5 Stars") (* or whatever else you want *)
    end tell
end if
 
on notifyTrack(myTrack, pos, txt)
    tell application "iTunes"
        set trkName to name of myTrack
        set trkArtist to artist of myTrack
        set trkAlbum to album of myTrack
        set trkTime to time of myTrack
        set trkRating to (rating of myTrack) / 20
        set trkPos to my getTimeString(pos)
        set artworkCount to count of artwork of myTrack
        if artworkCount > 0 then
            tell myTrack
                set trkArt to (data of artwork 1)
            end tell
        else
            set iTunesIcon to "Macintosh HD:Applications:iTunes.app:Contents:Resources:iTunes.icns"
            set trkArt to read (file iTunesIcon) as picture
        end if
        if (txt is equal to false) then
            set txt to trkName
            set trkInfo to trkPos & "/" & trkTime & " " & emdash & " " & my showStars(trkRating) & return & trkArtist & return & trkAlbum
        else
            set trkInfo to trkName & return & trkPos & "/" & trkTime & " " & emdash & " " & my showStars(trkRating) & return & trkArtist
            if (trkAlbum is not equal to "") then
                set trkInfo to trkInfo & " (" & trkAlbum & ")"
            end if
        end if
    end tell
    my showQSNotify(txt, trkArt, trkInfo)
end notifyTrack
 
on showStars(trkRating)
    set stars to ""
    repeat trkRating times
        set stars to stars & black_star
    end repeat
    repeat (5 - trkRating) times
        set stars to stars & " " & dot
    end repeat
    return stars
end showStars
 
on showQSNotify(txt, trkArt, trkInfo)
    tell application "GrowlHelperApp"
        set the allNotificationsList to {"Rating Change", "Song Skipping", "Song Info"}
        register as application ¬
            "Hotkey iTunes Notification" all notifications allNotificationsList default notifications allNotificationsList ¬
            icon of application "iTunes"
 
        if (trkArt is equal to missing value) then
            notify with name "Rating Change" title txt description trkInfo application name "Hotkey iTunes Notification"
        else
            notify with name "Rating Change" title txt description trkInfo application name "Hotkey iTunes Notification" pictImage the trkArt
        end if
    end tell
end showQSNotify
 
on showTrackInfo()
    try
        tell application "GrowlTunes"
            show current track
        end tell
    end try
end showTrackInfo
 
on getTimeString(secs)
    set no_seconds to the secs as number
    set no_minutes to no_seconds div 60
    set no_seconds to no_seconds mod 60
    if no_seconds < 10 then
        set seconds_text to "0" & (no_seconds as string)
    else
        set seconds_text to no_seconds as string
    end if
    if no_minutes ≥ 60 then
        set no_hours to no_minutes div 60
        set no_minutes to no_minutes mod 60
        if no_minutes < 10 then
            set no_minutes to "0" & (no_minutes as string)
        end if
        set minutes_text to (no_hours as string) & ":" & (no_minutes as string)
    else
        set minutes_text to no_minutes as string
    end if
 
    return minutes_text & ":" & seconds_text
end getTimeString

Download this script

Skipping

Sometimes, I find myself having a few hours of free time, where I want to just sit down and rate all my unrated songs. Instead of using the mouse to skip through every song (since I’ve already heard all of them, I just haven’t considered a rating for them), I have a script that skips a quarter of the song on each press, and places the playhead at 3 seconds from the end on the 4th activation. Useful for quickly skipping through a song.

property emdash : «data utxt2014» as Unicode text
property black_star : «data utxt272F» as Unicode text
property white_star : «data utxt2606» as Unicode text
property dot : «data utxt00B7» as Unicode text
 
set appName to "GrowlHelperApp"
set app2Name to "iTunes"
 
tell application "System Events"
    set appIsRunning to (name of processes contains appName) and (name of processes contains app2Name)
end tell
 
if appIsRunning then
    try
        tell application "iTunes"
            set myTrack to current track
            set dur to duration of myTrack
            set q1 to dur / 4
            set q2 to q1 * 2
            set q3 to q1 * 3
            set q4 to dur - 3
            set curPos to player position
            set counter to 0
            set theList to {q1, q2, q3, q4, dur}
            set pos to 0
            repeat while pos is less than or equal to curPos
                set counter to counter + 1
                set pos to item counter of theList
            end repeat
            if pos is less than 1 then set pos to 1
            set player position to pos
 
            if counter is greater than 3 then
                my notifyTrack(myTrack, player position, "Ending Song")
            else
                my notifyTrack(myTrack, player position, "Song Skip")
            end if
            (* my showTrackInfo() *)
        end tell
    end try
end if
 
on notifyTrack(myTrack, pos, txt)
    tell application "iTunes"
        set trkName to name of myTrack
        set trkArtist to artist of myTrack
        set trkAlbum to album of myTrack
        set trkTime to time of myTrack
        set trkRating to (rating of myTrack) / 20
        set trkPos to my getTimeString(pos)
        set artworkCount to count of artwork of myTrack
        if artworkCount > 0 then
            tell myTrack
                set trkArt to (data of artwork 1)
            end tell
        else
            set iTunesIcon to "Macintosh HD:Applications:iTunes.app:Contents:Resources:iTunes.icns"
            set trkArt to read (file iTunesIcon) as picture
        end if
        if (txt is equal to false) then
            set txt to trkName
            set trkInfo to trkPos & "/" & trkTime & " " & emdash & " " & my showStars(trkRating) & return & trkArtist & return & trkAlbum
        else
            set trkInfo to trkName & return & trkPos & "/" & trkTime & " " & emdash & " " & my showStars(trkRating) & return & trkArtist
            if (trkAlbum is not equal to "") then
                set trkInfo to trkInfo & " (" & trkAlbum & ")"
            end if
        end if
    end tell
    my showQSNotify(txt, trkArt, trkInfo)
end notifyTrack
 
on showStars(trkRating)
    set stars to ""
    repeat trkRating times
        set stars to stars & black_star
    end repeat
    repeat (5 - trkRating) times
        set stars to stars & " " & dot
    end repeat
    return stars
end showStars
 
on showQSNotify(txt, trkArt, trkInfo)
    tell application "GrowlHelperApp"
        set the allNotificationsList to {"Rating Change", "Song Skipping", "Song Info"}
        register as application ¬
            "Hotkey iTunes Notification" all notifications allNotificationsList default notifications allNotificationsList ¬
            icon of application "iTunes"
 
        if (trkArt is equal to missing value) then
            notify with name "Song Skipping" title txt description trkInfo application name "Hotkey iTunes Notification"
        else
            notify with name "Song Skipping" title txt description trkInfo application name "Hotkey iTunes Notification" pictImage the trkArt
        end if
    end tell
end showQSNotify
 
on showTrackInfo()
    try
        tell application "GrowlTunes"
            show current track
        end tell
    end try
end showTrackInfo
 
on getTimeString(secs)
    set no_seconds to the secs as number
    set no_minutes to no_seconds div 60
    set no_seconds to no_seconds mod 60
    if no_seconds < 10 then
        set seconds_text to "0" & (no_seconds as string)
    else
        set seconds_text to no_seconds as string
    end if
    if no_minutes ≥ 60 then
        set no_hours to no_minutes div 60
        set no_minutes to no_minutes mod 60
        if no_minutes < 10 then
            set no_minutes to "0" & (no_minutes as string)
        end if
        set minutes_text to (no_hours as string) & ":" & (no_minutes as string)
    else
        set minutes_text to no_minutes as string
    end if
 
    return minutes_text & ":" & seconds_text
end getTimeString

Download this script

This method works well with a couple of smart playlists and clever manipulation of the Party Shuffle feature. I have two smart playlists (one of them is used to filter out tv shows and movies, but not video clips). One is named “Other Video”, and has the following rules:

Match any of the following:
Video kind is Movie
Video kind is TV Show

The other is named “All Unrated”, and has the following rules:

Match all of the following:
My rating is less than 1 star
Podcast is false
Playlist is not Other Video

Finally, in Party Shuffle, at the bottom, I have Source: “All Unrated”, Display 5 recently played songs, and 15 upcoming songs. This way, even though the song I just rate will be removed from the “All Unrated” smart playlist, it won’t stop playing as it’s in the Party Shuffle playlist.

Artwork

I first ran “Get Album Artwork” in iTunes, but obviously that had a fairly limited success as a lot of my music has vital information like Album missing, and also a lot of the music I listen to isn’t even in the iTunes store. To cover the gap, I’m a fanatic GrowlTunes user, which does all the heavy work of fetching album covers (sometimes more successfully than others). GrowlTunes first looks for album artwork in the song itself, and if it doesn’t find any it then fetches it from the internet to display the Growl alert. What it does NOT do is save it with the song, but it DOES save it locally so it doesn’t have to fetch it again (in my opinion this is a very good thing as anything under a 95% success ratio you’ll want to review, and GrowlTunes is more like 70%). So what I’ve done is prepared a script that, for the current track, looks at the default GrowlTunes location, and if it finds an album cover it adds it to the song (to run it, you will need to replace your own short user name at the first line of the script):

property myUserName : "Constantinos"
property appName : "iTunes"
 
tell application "System Events" to set appIsRunning to name of processes contains appName
 
if appIsRunning then
    tell application "iTunes"
        try
            set myTrack to current track
            set trackName to name of myTrack
            if (trackName is equal to "") then
                set trackName to "Unknown Track"
            end if
            set trackArtist to artist of myTrack
            if (trackArtist is equal to "") then
                set trackArtist to "Unknown Artist"
            end if
            set trackAlbum to album of myTrack
            if (trackAlbum is equal to "") then
                set trackAlbum to "Unknown Album"
            end if
        end try
    end tell
 
    set artworkFilename to "/Users/" & myUserName & "/Library/Images/Music/" & trackArtist & "/" & trackAlbum & "/Tracks/" & trackName & "/Track.png"
    set deleteFilename to "Macintosh HD:Users:" & myUserName & ":Library:Images:Music:" & trackArtist & ":" & trackAlbum & ":Tracks:" & trackName & ":Track.png"
 
    set deleteCoverFilename to "Macintosh HD:Users:" & myUserName & ":Library:Images:Music:" & trackArtist & ":" & trackAlbum & ":Cover.png"
    set albumCoverFilename to "/Users/" & myUserName & "/Library/Images/Music/" & trackArtist & "/" & trackAlbum & "/Cover.png"
 
    set tempfile to "Macintosh HD:tmp:temporary.pict"
 
    tell application "Image Events"
        (* set artworkFile to (POSIX file artworkFilename)
        set myImage to open (artworkFile as alias) *)
        set myImage to open artworkFilename
        try
            save myImage as PICT in (file tempfile)
        on error
            try
                set deleteFilename to deleteCoverFilename
                set myImage to open albumCoverFilename
                save myImage as PICT in (file tempfile)
            on error
                return
            end try
        end try
        close myImage
    end tell
 
    tell application "iTunes"
        set myTrack to current track
        set artworkCount to count of artwork of myTrack
        set myArt to read (file tempfile) from 513 as picture
        if artworkCount > 0 then
            set data of artwork (artworkCount + 1) of current track to myArt
        else
            set data of artwork 1 of current track to myArt
        end if
    end tell
 
    tell application "Image Events"
        delete (file tempfile)
        delete (file deleteFilename)
    end tell
 
end if

Download this script

Notifications

The first two scripts use the same “Hotkey iTunes Notification” application name to register with Growl, with three types of notification: “Rating Change”, “Song Skipping” and “Song Info”. The last one simply brings up a detailed notification dialog with the current song’s playhead position, title, artist, rating, album and album art, which can all fit in the small “Smoke” style notification window. If you’re interested in that, the script follows:

property emdash : «data utxt2014» as Unicode text
property black_star : «data utxt272F» as Unicode text
property white_star : «data utxt2606» as Unicode text
property dot : «data utxt00B7» as Unicode text
 
set appName to "GrowlHelperApp"
set app2Name to "iTunes"
 
tell application "System Events"
    set appIsRunning to (name of processes contains appName) and (name of processes contains app2Name)
end tell
 
if appIsRunning then
    tell application "iTunes"
        my notifyTrack(current track, player position, false)
    end tell
end if
 
on notifyTrack(myTrack, pos, txt)
    tell application "iTunes"
        set trkName to name of myTrack
        set trkArtist to artist of myTrack
        set trkAlbum to album of myTrack
        set trkTime to time of myTrack
        set trkRating to (rating of myTrack) / 20
        set trkPos to my getTimeString(pos)
        set artworkCount to count of artwork of myTrack
        if artworkCount > 0 then
            tell myTrack
                set trkArt to (data of artwork 1)
            end tell
        else
            set iTunesIcon to "Macintosh HD:Applications:iTunes.app:Contents:Resources:iTunes.icns"
            set trkArt to read (file iTunesIcon) as picture
        end if
        if (txt is equal to false) then
            set txt to trkName
            set trkInfo to trkPos & "/" & trkTime & " " & emdash & " " & my showStars(trkRating) & return & trkArtist & return & trkAlbum
        else
            set trkInfo to trkName & return & trkPos & "/" & trkTime & " " & emdash & " " & my showStars(trkRating) & return & trkArtist
            if (trkAlbum is not equal to "") then
                set trkInfo to trkInfo & " (" & trkAlbum & ")"
            end if
        end if
    end tell
    my showQSNotify(txt, trkArt, trkInfo)
end notifyTrack
 
on showStars(trkRating)
    set stars to ""
    repeat trkRating times
        set stars to stars & black_star
    end repeat
    repeat (5 - trkRating) times
        set stars to stars & " " & dot
    end repeat
    return stars
end showStars
 
on showQSNotify(txt, trkArt, trkInfo)
    tell application "GrowlHelperApp"
        set the allNotificationsList to {"Rating Change", "Song Skipping", "Song Info"}
        register as application ¬
            "Hotkey iTunes Notification" all notifications allNotificationsList default notifications allNotificationsList ¬
            icon of application "iTunes"
 
        if (trkArt is equal to missing value) then
            notify with name "Song Info" title txt description trkInfo application name "Hotkey iTunes Notification"
        else
            notify with name "Song Info" title txt description trkInfo application name "Hotkey iTunes Notification" pictImage the trkArt
        end if
    end tell
end showQSNotify
 
on showTrackInfo()
    try
        tell application "GrowlTunes"
            show current track
        end tell
    end try
end showTrackInfo
 
on getTimeString(secs)
    set no_seconds to the secs as number
    set no_minutes to no_seconds div 60
    set no_seconds to no_seconds mod 60
    if no_seconds < 10 then
        set seconds_text to "0" & (no_seconds as string)
    else
        set seconds_text to no_seconds as string
    end if
    if no_minutes ≥ 60 then
        set no_hours to no_minutes div 60
        set no_minutes to no_minutes mod 60
        if no_minutes < 10 then
            set no_minutes to "0" & (no_minutes as string)
        end if
        set minutes_text to (no_hours as string) & ":" & (no_minutes as string)
    else
        set minutes_text to no_minutes as string
    end if
 
    return minutes_text & ":" & seconds_text
end getTimeString

Download this script

That’s pretty much it… Enjoy!

Automating backup of Flash drives

Constantinos — Mon, 05 Mar 2007 21:32:26 +0000

I have a lot of my critical work on a few flash drives which I carry around with me constantly, mainly because I work on a number of machines and would like to have a central repository of my work. After losing one of the drives recently though (bound to happen sooner or later), I looked further into automating the backup process (I had lost about 2 days of work). That’s when I stumbled accross this hint on macosxhints.com, but the script didn’t exactly fulfil what I had imagined my automated process to do.

Ideally, the automated backup process would have these features:

Not require installation of any third party app
Have the ability to somewhat customize the backup script for each thumb drive
Have the backup script silently run whenever the thumb drive is mounted
Require little to no set up for each new thumb drive that I want to backup
Support spaces in Volume names
Not try to backup the boot drive under any circumstances (don’t ask…)

Updated 2007-03-10: I updated the backup script to include automated handling of archives, and keeps an arbitrary number (specified in the preferences of the script) of incremental archives using rsync's --link-dest parameter, as recommended by John in the comments. This creates what functionally amounts to FULL backups, but with a fraction of the space needed for an actual tar backup. Also it can be configured to keep at most one backup per day, or with minor editing at most one backup for any period of time.

Updated 2007-03-18: I've created a second script which can be used as a drag-n-drop solution. Simply save the script as an application bundle, save it somewhere handy, and drag it to your dock. Now you can drag your thumb drive on the script which will perform the backup, and then eject your drive!

Updated 2008-03-10: Folder action modified to work with Leopard. Well, more like hacked at this point, but it seems to work.

Now to satisfy the first parameter, using Do Something When was out of the question, even though it seems like a good piece of software. That’s when I turned to Fodler Actions, and found this hint again on macosxhints.com. I then proceeded to read the Apple-published Folder Action for automating backups (which, again, didn’t do quite what I wanted), so I came up with this:

A folder action that scans the root folder of the mounted volume, and looks for (one of) a specified file name.

property backup_script : "rsync.app" (* add/change this string to match the name of your script *)
 
on adding folder items to this_folder after receiving these_volumes
    tell application "Finder"
        try
            set the volume_list to every file of this_folder
 
            (* go through all entries in /Volumes/ *)
            repeat with i from 1 to number of items in volume_list
                set this_item to the original item of item i of volume_list
                if the kind of this_item is "Volume" then
                    set this_disk to (this_item as alias)
 
                    (* is this item the newly mounted disk? *)
                    if this_disk is in these_volumes then
 
                        (* iterate through all files in the root of disk *)
                        set searchCmd to "ls -d " & quoted form of POSIX path of this_disk & backup_script
                        (* check to see if a backup script is available *)
                        set searchResult to ""
                        try
                            set searchResult to do shell script searchCmd
                        end try
                        (* run the backup script *)
                        if (searchResult starts with "/Volumes") then
                            set backupFile to POSIX file searchResult as alias
                            open backupFile
                        end if
 
                    end if
                end if
            end repeat
        on error error_message number error_number
            if the error_number is not -128 then
                display dialog error_message buttons {"OK"} default button 1
            end if
        end try
    end tell
end adding folder items to

Download this script

If you already know how to apply folder actions, just save the script above and apply it as a folder action to the /Volumes/ folder. If you don’t know (or don’t remember) how to do that, re-iterating the instructions from this Apple page, follow these steps to do it:

Copy the above code in Script Editor
Save it as a script in /Library/Scripts/Folder Action Scripts/, and give it a descriptive name
In Finder, click Go -> Go to Folder (or just press cmd-shift-G), and type /Volumes/.
Launch the Folder Actions Setup utility (probably located in /Applications/Apple Script/ folder)
Click the Add Folder Action (round plus) button at the bottom left
Drag the small folder icon from the Finder window title bar into the Choose Folder sheet dialog, and click ok.
From the dialog that comes up, chose the script you just saved.
You’re done.

Alternatively (or additionally), you can save this script as an application bundle, save it somewhere handy, and drag it to your dock. When you drag a thumb drive on this application the backup process will start, and as soon as it's done the drive will eject.

property backup_script : "rsync" (* add/change this to match the name of your script *)
 
on open dropped_item
    set this_vol_alias to (dropped_item as alias)
    try
        tell application "Finder"
            if the kind of this_vol_alias is "Volume" then
                set the file_list to every file of this_vol_alias
                repeat with j from 1 to number of items in file_list
                    (* check to see if a backup script is available *)
                    set this_file to name of item j of file_list
                    if this_file is equal to (backup_script & ".app") then
                        open item j of file_list (* run the backup script *)
                    end if
                end repeat
            else
                display alert "This script can only be executed on volumes"
                return
            end if
        end tell
 
        delay 2 (* give some time for the backup script to actually launch *)
        tell application "Finder"
            try
                set bakapp to creator type of process backup_script
                repeat while bakapp is not equal to ""
                    delay 1 (* the backup is still running, we can check again in a second *)
                    set bakapp to creator type of process backup_script
                end repeat
            on error
                if (ejectable of this_vol_alias is true) then
                    (* display alert POSIX path of dropped_item *)
                    eject this_vol_alias
                end if
            end try
        end tell
 
    on error error_message number error_number
        if the error_number is not -128 then
            display dialog error_message buttons {"OK"} default button 1
        end if
    end try
end open

Download this script

Now, for the modified backup script. The properties at the top can be modified on a per copy basis to customize the function of the script.

property archive_backup : true
property number_of_archives : 3 (* 0 for unlimited *)
property with_administrator_privileges : false
property one_archive_per_day : true
 
property display_notification : false
property backup_target : "Backups/" (* MUST be a folder location with trailing slash! Always relative to home folder *)
 
property rsync_params : "-aEz --delete-excluded"
(* END OF PREFERENCES *)
 
set WhereImRunningFrom to path to me
tell application "Finder"
    (* can't run from the script editor *)
    set AppCreator to creator type of WhereImRunningFrom
    if AppCreator is "ToyS" then
        activate of me
        beep
        display alert "This script cannot run directly from ScriptEditor"
        return
    end if
 
    (* NEVER run from the hard drive! *)
    set bootVolume to name of disk of home (* safety feature! *)
    set NameOfDisk to name of disk of WhereImRunningFrom
    if NameOfDisk is bootVolume then
        beep
        display alert "Should not run this script from the boot volume!"
        return
    end if
 
    (* setup backup dir *)
    set homeDir to path to home folder from user domain
    set backup_folder to POSIX path of homeDir & backup_target
    try
        (* quick and dirty check to see if folder exists - must be a good way to do this in applescript? *)
        do shell script "cd " & backup_folder
    on error
        try
            do shell script "mkdir " & backup_folder
        on error
            display alert "There was an error creating the backup folder " & backup_folder
            return
        end try
    end try
 
    (* find source and target *)
    set backupBase to NameOfDisk & "-Backup"
    set targetDir to backup_folder & quoted form of backupBase
    set sourceDir to quoted form of ("/Volumes/" & NameOfDisk & "/")
 
    (* set up archive filename *)
    if archive_backup then
        set thedate to current date
        set theday to day of thedate
        set themonth to month of thedate
        set theyear to year of thedate
        set thetime to time of thedate
 
        set thedate to "-" & theyear & "-" & shortMonth(themonth) of me & "-" & theday as string
        if not one_archive_per_day then set thedate to thedate & "-" & thetime as string
 
        set backupFolder to quoted form of (backup_folder & backupBase & thedate  & "/")
    end if
end tell
 
(* do the backup *)
(* try *)
if with_administrator_privileges then
    set excluded to " "
else
    set excluded to " --exclude='.Trash*' --exclude='.Spotlight*'  "
end if
 
if archive_backup then
    set posixDir to POSIX file backup_folder
    set fileList to list folder posixDir
    set archiveList to {}
    tell application "Finder"
        (* Search for existing backups *)
        repeat with i from 1 to number of items in fileList
            set thisFile to item i of fileList
            set filePath to path to resource thisFile in bundle posixDir
            if thisFile starts with backupBase then
                set archiveList to archiveList & POSIX path of filePath
            end if
        end repeat
    end tell
 
    (* List existing backups in order of last modified date *)
    set latestArchive to ""
    set linkDest to ""
    set listString to ""
    repeat with x from 1 to number of items in archiveList
        set listString to listString & " " & quoted form of item x of archiveList
    end repeat
    set newString to do shell script "ls -dt " & listString (* sort files by modified date *)
    set theList to (paragraphs of newString)
 
    (* Clear out outdated backups *)
    if (number of items in theList is greater than number_of_archives) and (number_of_archives is greater than 0) then
        repeat with y from (number_of_archives + 1) to (number of items in theList)
            do shell script "rm -Rf " & quoted form of item y of theList
        end repeat
    end if
    if number of items in theList is greater than 0 then
        set latestArchive to quoted form of item 1 of theList
        if latestArchive is equal to backupFolder then
            (* Preserve same target folder *)
            if number of items in theList is greater than 1 then
                set latestArchive to quoted form of item 2 of theList
            else
                set latestArchive to ""
            end if
        end if
    end if
 
    if latestArchive is not equal to "" then
        set linkDest to " --link-dest=" & latestArchive
    end if
    set theScript to "rsync " & rsync_params & linkDest & excluded & sourceDir & " " & backupFolder & "; touch " & backupFolder
else
    set theScript to "rsync " & rsync_params & excluded & sourceDir & " " & targetDir & "; touch " & targetDir
end if
 
if with_administrator_privileges then
    do shell script theScript with administrator privileges
else
    do shell script theScript
end if
 
activate of me
beep
if display_notification then display alert NameOfDisk & " drive backed up"
(*
on error
    display alert "There was an error backing up " & NameOfDisk
end try
*)
 
 
to shortMonth(themonth)
    set MonthList to {January, February, March, April, May, June, July, August, September, October, November, December}
    set mm to 1
    repeat until item mm of MonthList = themonth
        copy mm + 1 to mm
    end repeat
    if mm < 10 then copy "0" & mm to mm
    return mm
end shortMonth

Download this script

Copy the above code in Script Editor, and save it as an Application bundle giving it the name "rsync". If you wish to give it a different name, or maintain a number of copies each with a different name, make sure to modify the first line of the Folder Action script appropriately.

Finally, I can just drop a copy of the rsync application bundle in any thumb drive I want to keep a backup of, and apply the Folder Action to any computer I want to maintain backups on. Since the backup script is using rsync for the backup, I can have multiple backups on any number of computers and they will all mirror the contents of the thumb drive whenever the thumb drive is mounted on them. Additionally, a tar-gzipped copy of the thumb drive can optionally be created with a date stamp for archiving. Deletion of old archives must be managed manually.

If you are having permission issues with some of the files on one of your thumb drives, you can enable the with_administrator_privileges property in the backup script. This will cause the script to ask you for a password every time the thumb drive is mounted before performing the backup, but will perform the backup as an administrator eliminating any permission issues.

I feel that this script can still be improved, but for now it works just fine for my needs. If you have any suggestions for improving this process, feel free to add them in the comments.